Ankündigung

Einklappen
Keine Ankündigung bisher.

Script zum Aufwachen und automatischen mounten eines Ordners auf Synology-NAS

Einklappen
X
  • Filter
  • Zeit
  • Anzeigen
Alles löschen
neue Beiträge

  • Allgemein Script zum Aufwachen und automatischen mounten eines Ordners auf Synology-NAS

    Hallo,

    seit kurzem habe ich ein Synology-NAS DS713+. Auf diesem habe ich meine ganzen Filme und Serien (im Ordner TV) liegen. Da leider das NAS für das Transcodieren aufs ipad zu schwach ist, möchte ich auf meinem Mac Mini den Plex Server installieren. Das NAS wird zu einem best. Zeitpunkt gestartet (gegen Mittag) und gegen Mitternacht wieder ausgeschalten. Zu diesem Zeitpunkt habe ich kein Problem bezügl. des Automounts. Wenn ich jedoch einmal den Mini vor Mittag starte so hätte ich gerne das ein Script startet, welches ein Magic Packet an die Syno schickt, ca. 60 sec. wartet und dann den Ordner "TV" mountet.

    Als ich einen WHS hatte da bediente ich mich folgenden Scriptes:

    Code:
    delay 40
    repeat with idx from 1 to 10
    set ping_result to (do shell script "ping -c 1 IP-Adresse-Syno")
    if ping_result contains "100% packet loss" then
    delay 5
    else
    exit repeat
    end if
    end repeat
    if idx ≥ 10 then return -- failure to connect
    mount volume "afp://IP-Adresse-Syno/TV"
    Das hat natürlich super funktioniert, aber reagiert diese Syno auf den Ping-Befehl leider nicht. Auch hat Mountain Lion keinen Befehl um Magic Packets (damit startet die Syno) abzusenden. Bei Recherchen im Internet habe ein WOL-Programm hier gefunden. Dieses Programm habe ich in den "Programm-Ordner" gegeben und bei einem Test im Terminal den folgenden Befehl eingegeben:

    /Application/wol 00:00:00:00:00 (Mac-Adresse der Syno)
    Damit ist die Syno problemlos aufgewacht.

    Jetzt meine Frage, wie ich am besten diesen Befehl/Programm in das oben angeführte Skript einbauen kann, damit beim Start von ML die Syno aufgeweckt und nach einer kurzen Wartezeit der Ordner TV gemountet wird.

    Bin für jede Hilfe dankbar

    Zusatz: Hier wird beschrieben wie der WOL-Befehl mit dem Programm SleepWatcher eingebunden wird. Mir wäre jedoch eine "zusammengefasste Lösung" (WOL + Automount) lieber.

    Huberer
    iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
    iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
    HTPC: Nvidia Shield TV 16GB mit Android TV
    iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

  • #2
    Hi,

    das müsste eigentlich mit einem Shellscript Aufruf klappen:

    Code:
    do shell script "/Applications/wol 00:00:00:00:00"
    Also z.B. so:

    Code:
    do shell script "/Applications/wol 00:00:00:00:00"
    delay 40
    repeat with idx from 1 to 10
        set ping_result to (do shell script "ping -c 1 IP-Adresse-Syno")
        if ping_result contains "100% packet loss" then
            delay 5
        else
            exit repeat
        end if
    end repeat
    if idx ≥ 10 then return -- failure to connect
    mount volume "afp://IP-Adresse-Syno/TV"
    MAC Adresse und Pfad zum WOL Tool musst Du natürlich anpassen.

    lg

    Michael
    HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

    Kommentar


    • #3
      Hallo Michael,

      danke für deine Hilfe. Das Aufwecken hat einmal funktioniert. Nur leider bekomme ich jetzt folgende Fehlermeldung:

      Bildschirmfoto 2013-01-07 um 13.10.38.png

      anscheinend ist die Syno nicht schnell genug wach, dass sie auf den Ping reagiert. Hab schon die Zeiten bei beiden "delays" im Script von delay 40 auf 80 (1. delay) und delay 5 (2. delay) auf 40 angehoben, aber diese Meldung kommt schon nach ca. 13 Sekunden.
      Muss noch diese "idx"-Syntax (od. Befehl) auch noch abgeändert werden?

      Ich weiß nicht ob es auch von Bedeutung ist, ich habe das Script im Automator (Arbeitsablauf => Run AppleScript => AppleScript ausführen) testweise laufen lassen (mittels des grünen Start-Buttons).

      Danke nochmals
      iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
      iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
      HTPC: Nvidia Shield TV 16GB mit Android TV
      iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

      Kommentar


      • #4
        Hallo Huberer,

        Das Script macht im Grunde folgendes:

        Eine Repeat Schleife wird bis zu 10 mal durchlaufen, jeweils mit einer Verzögerung von 5 Sekunden. Bei jedem Durchlauf wird genau 1 Ping an Dein NAS gesendet. Antwortet das NAS, dann wird die Schleife per Exit Repeat verlassen. Bleibt die Antwort aus (100% packet loss), dann wird die maximale Anzahl Wiederholungen durchlaufen. In der Variablen idx wird die Anzahl der Durchläufe gespeichert. Ist die Zahl kleiner 10, dann hat Dein NAS geantwortet und es wird der Mount Befehl angeworfen. Ist sie grösser oder gleich 10, dann nicht. In diesem Fall bricht das Script ab.

        Wenn auf den Ping eine Antwort erfolgt, dann bedeutet das noch lange nicht, dass das NAS auch bereit ist. Das ist nur ein Zeichen für eine funktionsfähige Netzwerkkarte. Es könnte also sein, dass das NAS auf den Ping reagiert, die Repeat Schleife verlassen wird, der Mount Befehl aber trotzdem ins Leere läuft. Vielleicht sollte man noch einen Delay zwischen der vorletzten und letzten Zeile (mount...) einsetzen.

        Da die Schleife nach einem erfolgreichen Ping verlassen wird, bringt die Verlängerung des 5 Sekunden Delays eigentlich nichts. Das NAS wird ja durch WOL geweckt. Damit sollte es auch nach dem 40 Sekunden Delay bereits auf den Ping reagieren. Also wird die Schleife vermutlich gleich nach dem ersten Versuch verlassen.

        Was mich an Deinem Screenshot wundert ist allerdings das angezeigte Symbol. Denn dabei handelt es sich eigentlich um eine Automator Meldung. Das Script selbst ist aber AS und hat mit dem Automator direkt nichts zu tun. Es sei denn, das AS Script wäre ein Bestandteil einer Automator Aktion?

        Ich werde das Script zu Hause nochmals genauer anschauen. Dann kann ich sicher mehr sagen.

        lg

        Michael
        HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

        Kommentar


        • #5
          Hallo Michael,

          danke wiederum für deine Info. Wie schon geschrieben habe ich das ganze unter Automator gemacht. Warum? Bin nach dieser Anleitung hier vorgegangen, deswegen auch mit Automator (Run AppleScript => AppleScript ausführen). Aber lt. dem Screenshot erhält er ja keine Rückantwort von der Netzwerkkarte.
          Also nochmals zur Info, dass die Syno ausgeschalten ist, aber durch ein WOL-Signal aufgeweckt werden kann. Vielleicht kann da die Netzwerkkarte bis zum Hochfahren (ca. 60 sec) noch nicht auf den Ping-Befehl antworten.
          Vielleicht wäre es besser ein delay zwischen dem wol und den ping einzufügen, oder?

          Edit: hab jetzt testweise ein delay 40 vor der letzten Zeile (mount volume...) eingefügt und bekomme ich dieselbe Screenshot-Meldung

          Edit2: nachdem der erste Start des Scripts ja die oben angeführte Meldung auswirft, habe ich etwas gewartet und das Script nochmals gestartet. Zu diesem Zeitpunkt war das NAS ja schon hochgefahren. Nach ca. 23 sec war dann der TV-Ordner gemountet ohne jeglich Fehlermeldung. Da ich nicht zu Hause bin habe ich das übers Internet (bin mit meinem Router zu Hause per VPN im selben Netzwerk verbunden) getestet.

          Also bräuchte ich einen zwischen der Beendigung des wol und des Beginns des ping eine zeitliche Pause. Was bewirkt den dieser delay 40 (in der 2. Zeile nach do shell script)?
          Zuletzt geändert von Huberer; 07.01.2013, 14:12.
          iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
          iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
          HTPC: Nvidia Shield TV 16GB mit Android TV
          iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

          Kommentar


          • #6
            Hallo Huberer,

            das Problem liegt im Script selbst. Wenn die zu pingende IP Adresse nicht antwortet, dann wirft das Script eine Fehlermeldung aus. Ich habe mal ein paar Anpassungen vorgenommen. Auf meinen System läuft es jetzt.

            Code:
            set ping_result to ""
            do shell script "/Applications/wol 00:00:00:00:00"
            delay 40
            repeat with idx from 1 to 10
                try
                    set ping_result to (do shell script "ping -c 1 IP-Adresse-Syno")
                end try
                if ping_result = "" or ping_result contains "100% packet loss" then
                    delay 5
                else
                    exit repeat
                end if
            end repeat
            if idx ≥ 10 then return -- failure to connect
            try
                mount volume "afp://IP-Adresse-Syno/TV"
            end try

            Wie schon geschrieben habe ich das ganze unter Automator gemacht.
            Das habe ich in der Eile im Büro überlesen

            Mit dem Automator habe ich noch nicht viel gemacht. Ich würde darauf verzichten. Kopiere den Scriptcode einfach in den Apple Script Editor und klicke auf den "Übersetzen" Button. Wenn das geklappt hat, dann wähle "Ablage / Sichern unter...". Gib dem Script einen Namen und wähle bei "Dateiformat" die Option "Programm" aus.

            sc1.jpg


            Du erhälts eine direkt ausführbare Datei. Automator ist dafür nicht nötig.

            sc2.jpg


            Da das Script jetzt nicht mehr im ersten Durchgang abbricht, ist auch kein weiterer Delay nötig. Wenn Du nach dem Mount noch ein Programm laden möchtest (z.B. iTunes, wie im verlinkten Beispiel), dann kannst Du das Script erweitern. In diesem Fall würde ich nach dem Mount noch eine Verzögerung einbauen und dann die zu startende Anwendung aufrufen. Beispiel:

            Code:
            set ping_result to ""
            do shell script "/Applications/wol 00:00:00:00:00"
            delay 40
            repeat with idx from 1 to 10
                try
                    set ping_result to (do shell script "ping -c 1 IP-Adresse-Syno")
                end try
                if ping_result = "" or ping_result contains "100% packet loss" then
                    delay 5
                else
                    exit repeat
                end if
            end repeat
            if idx ≥ 10 then return -- failure to connect
            try
                mount volume "afp://IP-Adresse-Syno/TV"
            end try
            
            delay 10
            
            tell application "iTunes" to activate
            lg

            Michael
            HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

            Kommentar


            • #7
              Super, danke es funktioniert einwandfrei. Nur habe ich eine weitere Frage. Wenn ich das Programm ausführe, bei bereits gestartetem NAS, dann braucht das Script ca. 46 sec bis der Ordner TV gemountet wird (nach Start des Scripts).

              Ist es möglich, diese Zeit irgendwie zu verkürzen? Weil wenn das NAS schon an ist kann ja der Ordner schon gemountet werden. Oder ist es in diesem Fall nicht möglich, da das Script wegen dem WOL auf das NAS warten muss? So ist mir aufgefallen, dass bei "Neustart" (aus ausgeschaltenem Zustand) die Syno im Finder aufscheint und nach gewisser Zeit der Ordner TV am Desktop.
              Zuletzt geändert von Huberer; 07.01.2013, 16:55.
              iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
              iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
              HTPC: Nvidia Shield TV 16GB mit Android TV
              iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

              Kommentar


              • #8
                Dein NAS braucht nach einem Neustart wahrscheinlich etwas Zeit um das System und die Freigaben hochzufahren. Deshalb die Verzögerung bis zum Auftauchen des Ordners. Aber für das Script spielt das eigentlich keine Rolle. Ich habe noch ein paar Änderungen eingebaut. Teste diese bitte mal. Da ich selbst kein NAS habe, kann ich das nur in der Theorie.

                Das Script arbeitet jetzt zweistufig. Es wird zunächst ein einzelner Ping abgesetzt. Wird dieser beantwortet (NAS "lebt" bereits), dann geht es nach einer Wartezeit von 5 Sekunden (aus Sicherheitsgründen) direkt weiter zum Mounting. Wird der Ping nicht beantwortet, dann läuft die bekannte Routine aus WOL, 40 Sek. Pause, 10 x Ping, etc.

                Um das Ganze etwas übersichtlicher zu machen, habe ich eine Variable für die IP Adresse des NAS eingebaut. So brauchst Du die Adresse nur an einer Stelle zu ändern, statt an mehreren. Du musst also nur die Adresse 127.0.0.1, die ich für den Test verwendet habe, gegen die NAS Adresse ersetzen.

                lg

                Michael

                Code:
                set IPAdresseSyno to "127.0.0.1"
                set ping_result to ""
                try
                    set ping_result to (do shell script "ping -c 1 " & IPAdresseSyno)
                end try
                if ping_result = "" or ping_result contains "100% packet loss" then
                    do shell script "/Applications/wol 00:00:00:00:00"
                    delay 40
                    repeat with idx from 1 to 10
                        try
                            set ping_result to (do shell script "ping -c 1 " & IPAdresseSyno)
                        end try
                        if ping_result = "" or ping_result contains "100% packet loss" then
                            delay 5
                        else
                            exit repeat
                        end if
                    end repeat
                    if idx ≥ 10 then return -- failure to connect
                else
                    delay 5
                end if
                try
                    mount volume "afp://" & IPAdresseSyno & "/TV"
                end try
                HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

                Kommentar


                • #9
                  Nachtrag...

                  Für die WOL Adresse habe ich auch gleich noch eine Variable eingebaut. Hier das angepasste Script:

                  Code:
                  set IPAdresseSyno to "127.0.0.1"
                  set WOLAdresse to "00:00:00:00:00"
                  
                  set ping_result to ""
                  try
                      set ping_result to (do shell script "ping -c 1 " & IPAdresseSyno)
                  end try
                  if ping_result = "" or ping_result contains "100% packet loss" then
                      do shell script "/Applications/wol " & WOLAdresse
                      delay 40
                      repeat with idx from 1 to 10
                          try
                              set ping_result to (do shell script "ping -c 1 " & IPAdresseSyno)
                          end try
                          if ping_result = "" or ping_result contains "100% packet loss" then
                              delay 5
                          else
                              exit repeat
                          end if
                      end repeat
                      if idx ≥ 10 then return -- failure to connect
                  else
                      delay 5
                  end if
                  try
                      mount volume "afp://" & IPAdresseSyno & "/TV"
                  end try
                  HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

                  Kommentar


                  • #10
                    Super, danke es funktioniert einwandfrei. Nur habe ich eine weitere Frage. Wenn ich das Programm ausführe, bei bereits gestartetem NAS, dann braucht das Script ca. 46 sec bis der Ordner TV gemountet wird (nach Start des Scripts).
                    Ist es möglich, diese Zeit irgendwie zu verkürzen? Weil wenn das NAS schon an ist kann ja der Ordner schon gemountet werden. Oder ist es in diesem Fall nicht möglich, da das Script wegen dem WOL auf das NAS warten muss?

                    Edit: so hab mal testweise die delay von 40 auf 30 reduziert und geht das Mounten schneller. Auch als ich von delay 30 auf 20 reduziert habe. Das Mounten des TV-Ordners im eingeschaltenen Zustand dauert ca. 26 sec. Ist jedoch das NAS ausgeschalten dann erhalte ich folgende Fehlermeldung:

                    Bildschirmfoto 2013-01-07 um 18.20.00.png

                    dies aber nur wenn delay auf 20 gestellt ist. Bei 30 kommt keine Fehlermeldung und wird der Ordner TV einwandfrei gemountet (wenn NAS ausgeschaltet).
                    iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
                    iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
                    HTPC: Nvidia Shield TV 16GB mit Android TV
                    iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

                    Kommentar


                    • #11
                      Ok, hast Du das jetzt mit dem alten Script probiert, oder schon mit dem eben geposteten? Damit sollte es im eingeschalteten Zustand nur ca. 5-10 Sekunden dauern.
                      HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

                      Kommentar


                      • #12
                        Hab noch das "alte" Script genommen. Das neue habe ich komplett übersehen.

                        So, nachdem ich die Anpassungen (IP und Mac-Adresse) gemacht habe funktioniert es jetzt einwandfrei. Wenn du jetzt glaubst ich ziehe den Hut vor dir hast du dich getäuscht...
                        Im Gegenteil ich verbeuge mich voller Ehrfurcht vor dir. Das was du da aus dem Hut gezaubert hast ist perfekt. Recht herzlichen Dank dafür.

                        Nur noch eine kleine Frage wenn ich nach dem mounten noch das Programm "Plex Media Server" starten möchte, nehme ich dann diesen Befehl:


                        tell application "Plex Media Server" to activate

                        am Ende des Scripts?
                        iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
                        iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
                        HTPC: Nvidia Shield TV 16GB mit Android TV
                        iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

                        Kommentar


                        • #13
                          Vielen Dank für die Blumen Freut mich, dass es jetzt klappt!

                          tell application "Plex Media Server" to activate
                          Das ist der richtige Befehl. Falls das Mounting einige Sekunden in Anspruch nehmen sollte, dann kannst Du noch einen Delay einbauen und am Ende anhängen , z.B. so:

                          Code:
                          delay 5
                          tell application "Plex Media Server" to activate
                          Das würde ich aber nur machen, wenn Probleme auftreten (PMS startet, bevor der mount Befehl fertig ist).

                          lg

                          Michael
                          HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

                          Kommentar


                          • #14
                            Guten Morgen Michael,

                            nochmals recht herzlichen Dank für deine Unterstützung und muss ich sagen, dass das Script perfekt funktioniert. Konnte es gestern am Abend wg. Besuch nur kurz testen und auch heute übers Internet funktioniert es super.

                            Eine Frage, nein eigentlich drei Fragen, aber habe ich noch:

                            1. wenn ich noch einen zweiten Ordner (Bsp. Musik) mounten möchte, dann füge ich folgende Zeile

                            mount volume "afp://" & IPAdresseSyno & "/Musik"
                            gleich nach der Zeile
                            mount volume "afp://" & IPAdresseSyno & "/TV"
                            ein?

                            2. sollte ich noch ein zweites Programm mitstarten wollen (Bsp. iTunes) dann mache ich es auch gleich mit tell application... gleich unter dem Befehl mit dem PMS? Brauche ich zwischen den beiden tell-Befehlen einen delay oder keinen? Wahrscheinlich wäre es besser oder?

                            3. darf ich dieses Script im Synology-Forum posten? Natürlich mit Verweis auf den Erstelller und auf das Forum bzw. Beitrag hier?

                            Danke nochmals für das perfekt laufende Script

                            Huberer
                            iMac-Home (Workstation+Server): Gigabyte Z87MX-D3H, i7-4770s@HD4600, 16GB Ram, 1TB SSD Samsung EVO, 3x3TB WD Red (9TB zusammengefasst), Elgato Sat-TV, Mavericks 10.9.5 mit Clover-Bootloader
                            iMac-Office: Gigabyte Z77MX-D3H, i7-3770S, Zotac Geforce GT640 passiv, 16GB Ram, 1x256GB SSD Crucial, 1x2TB WD Green (Daten-Platte), 1xPioneer BluRay-LW, 1xLiteon DVD-Brenner, Mavericks 10.9.5 mit Ozmosis-Bootloader
                            HTPC: Nvidia Shield TV 16GB mit Android TV
                            iOS-Geräte: iPad 4 32GB, iPhone 5S 32 GB

                            Kommentar


                            • #15
                              Hallo Huberer,

                              zu 1.

                              Das ist korrekt.

                              zu 2.

                              Das ist ebenfalls zutreffend. Einen Delay zwischen den zu startenden Anwendungen braucht es wahrscheinlich gar nicht. Den würde ich nur einfügen wenn Probleme auftreten sollten.

                              zu 3.

                              Kein Problem! Aller Applescript Code, der hier veröffentlicht wird, darf gerne kopiert, verändert, weiterverarbeitet werden. Das Script ist ja auch nur zum Teil auf meinem Mist gewachsen

                              Viel Spass mit Deinem NAS und dem Script

                              lg

                              Michael
                              HowTos: Mac Mini Mediacenter mit Plex oder XBMC / Logitech Harmony und der Mac

                              Kommentar

                              Lädt...
                              X